#!/usr/bin/wish

# about dialog box (actually lifted from edge editor)
# Copyright (c) 2000 Patrick H. Madden
# SUNY Binghamton Computer Science Dept
# pmadden@cs.binghamton.edu
# http://vlsicad.cs.binghamton.edu/~pmadden
# The latest version should be available at
#    http://vlsicad.cs.binghamton.edu/~pmadden/tkbib

#
# This file is part of tkbib
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2, or (at your option)
# any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; see the file COPYING.  If not, write to
# the Free Software Foundation, 59 Temple Place - Suite 330,
# Boston, MA 02111-1307, USA.
#CLIP+switchFrame+TEXT+28+Wed May 22 15:12:53 PDT 1996+4.40+#
# switchFrame w -- bargain basement animation!  When the after ticker ticks,
# we get called, and can swap the image on the About dialog!  Fun fun fun!
proc switchFrame {w} {
    global image_count image_max images delay

    # The image counter will be set to -1 when the dialog closes
    if {$image_count == -1} return

    $w config -image images($image_count)
    incr image_count
    if {$image_count == $image_max} {set image_count 0}

    after $delay "switchFrame $w"
}
#CLIP+aboutDialog+TEXT+43+2000/01/21 11:47:30+21.0+#
# aboutDialog -- opens up a dialog to tell you all about the editor, and
# lets you watch some truly stunning animation.
proc aboutDialog {} {
    global button version image_count images imagelogo

    toplevel .about -class Dialog
    wm title .about "About TkBib $version"
    wm iconname .about Dialog
    frame .about.top -relief raised -bd 1
    pack .about.top -side top -fill both
    frame .about.bot -relief raised -bd 1
    pack .about.bot -side bottom -fill both

    set m "TkBib $version
A LaTeX bib file editor
(c) 2000 Patrick H. Madden
SUNY Binghamton CSD
pmadden@cs.binghamton.edu
http://vlsicad.cs.binghamton.edu/~pmadden
Released under the Gnu Public License"
    message .about.top.msg -width 4i -text $m
    label .about.top.l -image images(0)
    label .about.top.r -image imagelogo
    pack .about.top.l .about.top.msg .about.top.r \
            -side left -expand 1 -fill both\
	    -padx 3m -pady 3m
    button .about.bot.ok -text "OK!" -command "set button 1"
    pack .about.bot.ok

    set oldFocus [focus]
    grab set .about
    focus .about

    set image_count 0
    switchFrame .about.top.l

    tkwait variable button
    set image_count -1
    destroy .about
    focus $oldFocus
    return $button
}
#CLIP+setup_about+TEXT+86+1999/12/16 22:34:47+4.0+#
# Various things to set up the about dialog so that we can call it
# from the main window menu bar.

set delay 1000
# Load up the list so that when the dialog opens, various propaganda
# images will be blasted at unsuspecting users.
set image_count 0
foreach f $aboutlist {
  image create photo images($image_count) -file $f
  incr image_count
}
set image_max $image_count
image create photo imagelogo -file $aboutlogo
#CLIP+pre+TEXT+1+2000/01/20 20:16:41+3.53+#